Pipeinfor循环中断了双引号变量-Pipeinforloopbreaksdoublequotedvariables

Thanks to Dave Benham's answer on a related issue I've found the solution!
It appeared to be a specific FOR /F bug in WinXP, and guess what, here I'm still on WinXP. To fix the main offender, the curl-pipe-jq-for-loop, I had to put ^" in front of and after the entire command. Thus the entire batchscript, which I've also further improved:

感谢Dave Benham对相关问题的回答,我找到了解决方案!它似乎是WinXP中一个特定的FOR / F错误,猜猜是什么,这里我还在使用WinXP。为了修复主要攻击者,curl-pipe-jq-for-loop,我必须在整个命令之前和之后放置^“。因此整个批处理脚本,我也进一步改进了:

@ECHO off
CLS

:: NPO JSON-extractor geschreven door Reino Wijnsma, 2015 (reino@degeelebosch.nl)

SET batchname=NPO JSON-extractor
SET version=1.1
TITLE %batchname% %version%

SET curl="C:\map with spaces\curl.exe"
SET jq="C:\map with spaces\jq-1.5rc1.exe"

:Check
IF EXIST %curl% (
    IF EXIST %jq% (
        GOTO Input
    ) ELSE (
        ECHO 'jq.exe' niet gevonden.
        ECHO.
        PAUSE
        GOTO :eof
    )
    GOTO Input
) ELSE (
    ECHO 'curl.exe' niet gevonden.
    ECHO.
    PAUSE
    GOTO :eof
)

:Input
ECHO Voer npo.nl programmalink in :
SET url=
SET /P url=
:: http://www.npo.nl/buitenhof/03-05-2015/VPWON_1232766/POMS_VPRO_850040 bijvoorbeeld
IF "%url%"=="" GOTO :eof

SETLOCAL ENABLEDELAYEDEXPANSION
FOR %%A IN ("%url%") DO (
    FOR /F "delims=" %%B IN ('^"%curl% -s http://e.omroep.nl/metadata/aflevering/%%~nxA ^| %jq% -R -r -s ".[1+index(\"(\"): rindex(\"^)\")]"^"') DO (
        ECHO.
        ECHO JSON:
        FOR /F "delims=" %%C IN ('ECHO %%B ^| %jq% .') DO ECHO %%C
        ECHO.
        FOR /F "tokens=1-3" %%C IN ('ECHO %%B ^| %jq% -r "[.tijdsduur,.start,.eind] | @tsv"') DO (
            ECHO Tijdsduur: %%C
            IF NOT "%%D"=="" (
                SET ss=%%D
                SET to=%%E
                SET /A "_ss=((1!ss:~0,2!-100)*3600)+((1!ss:~3,2!-100)*60)+(1!ss:~6,2!-100)"
                SET /A "_to=((1!to:~0,2!-100)*3600)+((1!to:~3,2!-100)*60)+(1!to:~6,2!-100)"
                ECHO Start:     %%D (!_ss!s^)
                ECHO Einde:     %%E (!_to!s^)
            )
        )
    )
)
ECHO.
ENDLOCAL
GOTO Input

Important notes for future reference:

重要说明供将来参考:

jq-syntax:           jq -R -r -s  '.[1+index("("):   rindex(")")]'
cmd-shell:           jq -R -r -s  ".[1+index(\"(\"): rindex(\")\")]"
for-loop:           'jq -R -r -s  ".[1+index(\"(\"): rindex(\"^)\")]"'
for-loop (path): '^"%jq% -R -r -s ".[1+index(\"(\"): rindex(\"^)\")]"^"'

- For the cmd-shell you have to escape the double quotes with a line-feed \.
- While 2 of the closing parenthesis are part of jq's syntax, the 1 between double quotes is not. So when in a for-loop, to prevent this for-loop from closing, you'd have to escape this one with a ^.
- When jq's executable path is put in a variable with double quotes, to circumvent a WinXP bug, you'd then also have to put the entire command between ^", because the parenthesis are now considered special characters! This workaround is compatible with Vista and beyond. (See also DosTips.com)

- 对于cmd-shell,您必须使用换行符\来转义双引号。 - 虽然两个右括号是jq语法的一部分,但双引号之间的1不是。所以当在for循环中,为了防止这个for循环关闭,你必须用^来逃避这个。 - 当jq的可执行路径放在带双引号的变量中时,为了规避WinXP错误,你还必须将整个命令放在^“之间,因为括号现在被认为是特殊字符!这种解决方法与Vista兼容以及。(另见DosTips.com)

Without being able to test it, I suggest to try your batch code as written below:

我无法测试它,我建议您尝试批量代码,如下所示:

@ECHO off
SET "curl=C:\map with spaces\curl.exe"
SET "jq=C:\map with spaces\jq.exe"
ECHO Enter npo.nl program-url :
SET "url="
SET /P "url="
:: http://www.npo.nl/buitenhof/03-05-2015/VPWON_1232766/POMS_VPRO_850040 for example
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /F "tokens=6 delims=/" %%A IN ("%url%") DO (
    FOR /F "delims=" %%B IN ('"%curl%" -s http://e.omroep.nl/metadata/aflevering/%%A') DO (
        FOR /F "delims=" %%C IN ('ECHO %%B ^| "%jq%" -R -r -s ".[1+index(\"^(\"): rindex(\"^)\")]"') DO (
            FOR /F "delims=" %%D IN ('ECHO %%C ^| "%jq%" -r .start') DO SET "ss=%%D"
            FOR /F "delims=" %%D IN ('ECHO %%C ^| "%jq%" -r .eind') DO SET "to=%%D"
            FOR /F "delims=" %%D IN ('ECHO %%C ^| "%jq%" -r .tijdsduur') DO SET "t=%%D"
            ECHO Start:    !ss!
            ECHO End:      !to!
            ECHO Duration: !t!
        )
    )
)
ENDLOCAL
PAUSE

The difference to your code is the position of the double quotes on assigning a string to an environment variable.

与代码的不同之处在于将字符串分配给环境变量时双引号的位置。

The command set is usually used with the parameter variable=value whereby this entire string is the parameter.

命令集通常与参数variable = value一起使用,整个字符串就是参数。

The command

SET "curl=C:\map with spaces\curl.exe"

puts the entire parameter of command set into double quotes. As a result the environment variable curl is defined with string C:\map with spaces\curl.exe without double quotes assigned to it.

将命令集的整个参数放入双引号中。因此,环境变量curl使用字符串C:\ map定义,其中spaces \ curl.exe没有分配双引号。

As an extra bonus of using double quotes on entire parameter string of command set, usually not visible trailing spaces and tabs at end of command line are now ignored.

作为在命令集的整个参数字符串上使用双引号的额外好处,现在忽略命令行末尾的通常不可见的尾随空格和制表符。

But using

SET curl="C:\map with spaces\curl.exe"

results in a completely different behavior. The entire parameter variable=value of command set is now not enclosed in double quotes. As a result of the different position of first double quote in the line the command set creates now the environment variable curl with assigning the string "C:\map with spaces\curl.exe" to it with the double quotes and with including perhaps also existing spaces and tabs at end of the command line.

导致完全不同的行为。整个参数变量=命令集的值现在不包含在双引号中。由于行中第一个双引号的位置不同,命令集现在创建环境变量curl,并使用双引号将字符串“C:\ map with spaces \ curl.exe”赋值给它,并且可能还包括命令行末尾的现有空格和制表符。

The batch code below copied into a batch file and executed demonstrates the differences:

下面的批处理代码复制到批处理文件中并执行,演示了不同之处:

@echo off
set "Var1=String with spaces and "double quotes""   
set Var2="String with spaces and "double quotes""
set Var3="String with spaces and "double quotes" and 3 trailing spaces"   
echo Var1=#%Var1%#
echo Var2=#%Var2%#
echo Var3=#%Var3%#
pause

Character # on output of the 3 variables is used to display where the assigned strings really start and end.

3个变量输出的字符#用于显示指定字符串真正开始和结束的位置。

The output is:

输出是:

Var1=#String with spaces and "double quotes"#
Var2=#"String with spaces and "double quotes""#
Var3=#"String with spaces and "double quotes" and 3 trailing spaces"   #

There are 3 trailing spaces at end of line defining Var1, but they are ignored as the double quotes enclose the entire parameter string of command set.

在定义Var1的行尾有3个尾随空格,但它们被忽略,因为双引号包含命令集的整个参数字符串。

There are no trailing spaces on line defining Var2, but all 4 double quotes are now part of the assigned string and not just the two double quotes around double quotes part of the string.

在定义Var2的行上没有尾随空格,但是所有4个双引号现在都是指定字符串的一部分,而不仅仅是字符串中双引号的两个双引号。

And last the line defining Var3 has also 3 trailing spaces which are also assigned to the variable which is very often not wanted on command lines referencing the value of the environment variable.

最后,定义Var3的行也有3个尾随空格,这些空格也分配给变量,这在引用环境变量值的命令行中通常不需要。

So best is to use always set "variable=value" even if whether variable name nor value contains a space. This notation is simply a protection against invisible trailing spaces or tabs being also assigned to the environment variable.

因此,即使变量名称和值是否包含空格,最好使用始终设置“variable = value”。这种表示法只是一种保护,可防止不可见的尾随空格或制表符也分配给环境变量。

As curl.exe with path containing spaces is now assigned to the environment variable curl without the double quotes, it is necessary to use the double quotes around the complete string containing %curl% which is here simply "%curl%". Same is true for %jq% as being not used inside a longer string and therefore always just "%jq%" can be used.

由于包含空格的路径的curl.exe现在已分配给没有双引号的环境变量curl,因此必须在包含%curl%的完整字符串周围使用双引号,这里只是“%curl%”。对于%jq%也是如此,因为未在较长的字符串中使用,因此始终只能使用“%jq%”。

One last hint: Debugging of batch files is often quite simple. Changing first line from @ECHO off to @ECHO ON or removing/commenting first line results in execution of batch file with showing also what is really executed by command line interpreter. The error in code can be often quickly found now by looking on the command lines processed.

最后一个提示:批处理文件的调试通常非常简单。将第一行从@ECHO更改为@ECHO ON或删除/注释第一行会导致执行批处理文件,同时显示命令行解释器实际执行的内容。现在,通过查看处理的命令行,可以快速找到代码中的错误。